vprops.f

Go to the documentation of this file.

      subroutine vprops 
C-----------------------------------------------------------------------
C
C     Set material properties
C
C     Material type: 0 for default  (PARAM and PCOND/PRHOCP)
C                    1 for constant props; 
C                    2 for fortran function;
C
C-----------------------------------------------------------------------
      include 'SIZE'
      include 'INPUT'
      include 'SOLN'
      include 'TSTEP'
      LOGICAL  IFKFLD,IFEFLD
C
      if (nio.eq.0.and.loglevel.gt.2)
     $   write(6,*) 'vprops', ifield
 
      nxyz1 = lx1*ly1*lz1
      nel   = nelfld(ifield)
      ntot1 = nxyz1*nel
C
      IF (istep.EQ.0) THEN
C
C        First time around, set defaults
C
         ifvarp(ifield) = .false.
         if (iflomach) ifvarp(ifield) = .true.
 
         if (.not.ifvarp(ifield)) then ! check all groups
            do iel=1,nel
               igrp  = igroup(iel)
               itype = matype(igrp,ifield)
               if(itype.ne.0) ifvarp(ifield) = .true.
            enddo
         endif
 
         itest = 0                        ! test against all processors
         if (ifvarp(ifield)) itest = 1
         itest = iglmax(itest,1)
         if (itest.gt.0) ifvarp(ifield) = .true.
 
      endif         
C
C     Fill up property arrays every time step
      DO 1000 iel=1,nel
C
         igrp=igroup(iel)
 
         if (ifuservp) then
C
C           User specified fortran function   (pff 2/13/01)
            CALL nekuvp (iel)
            difmin = vlmin(vdiff(1,1,1,iel,ifield),nxyz1)
            IF (difmin .LE. 0.0) THEN
               WRITE (6,100) difmin,ifield,igrp
               CALL exitt
            endif
C
         ELSE IF(matype(igrp,ifield).EQ.1)THEN
C
C           Constant property within groups of elements
C
            cdiff  = cpgrp(igrp,ifield,1)
            ctrans = cpgrp(igrp,ifield,2)
            CALL cfill(vdiff(1,1,1,iel,ifield),cdiff,nxyz1)
            CALL cfill(vtrans(1,1,1,iel,ifield),ctrans,nxyz1)
            IF (cdiff.LE.0.0) THEN
               WRITE(6,100) cdiff,ifield,igrp
  100          FORMAT(2x,'ERROR:  Non-positive diffusivity ('
     $        ,g12.3,') specified for field',i2,', group',i2
     $        ,' element',i4,'.'
     $        ,/,'ABORTING in VPROPS',//)
               CALL exitt
            endif
C
         ELSE IF(matype(igrp,ifield).EQ.2)THEN
C
C           User specified fortran function
C
            CALL nekuvp (iel)
C
            if(optlevel.le.2) then
              difmin = vlmin(vdiff(1,1,1,iel,ifield),nxyz1)
              IF (difmin .LE. 0.0) THEN
                 WRITE (6,100) difmin,ifield,igrp
                 CALL exitt
              endif
            endif
C
         ELSE IF(matype(igrp,ifield).EQ.0)THEN
C
C           Default constant property
C
            cdiff  = cpfld(ifield,1)
            ctrans = cpfld(ifield,2)
c           write(6,*) 'vdiff:',ifield,cdiff,ctrans
            CALL cfill(vdiff(1,1,1,iel,ifield),cdiff,nxyz1)
            CALL cfill(vtrans(1,1,1,iel,ifield),ctrans,nxyz1)
            IF (cdiff.LE.0.0) THEN
               WRITE(6,200) cdiff,ifield
  200          FORMAT(2x,'ERROR:  Non-positive diffusivity ('
     $        ,g12.3,') specified for field',i2,'.',/
     $        ,'ABORTING in VPROPS',//)
               CALL exitt
            endif
         endif
C
 1000 CONTINUE
C
      return
      end
C