dzsum1.f

Go to the documentation of this file.

      DOUBLE PRECISION FUNCTION dzsum1( N, CX, INCX )
*
*  -- LAPACK auxiliary routine (version 3.0) --
*     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
*     Courant Institute, Argonne National Lab, and Rice University
*     October 31, 1992
*
*     .. Scalar Arguments ..
      INTEGER            incx, n
*     ..
*     .. Array Arguments ..
      COMPLEX*16         cx( * )
*     ..
*
*  Purpose
*  =======
*
*  DZSUM1 takes the sum of the absolute values of a complex
*  vector and returns a double precision result.
*
*  Based on DZASUM from the Level 1 BLAS.
*  The change is to use the 'genuine' absolute value.
*
*  Contributed by Nick Higham for use with ZLACON.
*
*  Arguments
*  =========
*
*  N       (input) INTEGER
*          The number of elements in the vector CX.
*
*  CX      (input) COMPLEX*16 array, dimension (N)
*          The vector whose elements will be summed.
*
*  INCX    (input) INTEGER
*          The spacing between successive values of CX.  INCX > 0.
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            i, nincx
      DOUBLE PRECISION   stemp
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
      dzsum1 = 0.0d0
      stemp = 0.0d0
      IF( n.LE.0 )
     $   RETURN
      IF( incx.EQ.1 )
     $   GO TO 20
*
*     CODE FOR INCREMENT NOT EQUAL TO 1
*
      nincx = n*incx
      DO 10 i = 1, nincx, incx
*
*        NEXT LINE MODIFIED.
*
         stemp = stemp + abs( cx( i ) )
   10 CONTINUE
      dzsum1 = stemp
      RETURN
*
*     CODE FOR INCREMENT EQUAL TO 1
*
   20 CONTINUE
      DO 30 i = 1, n
*
*        NEXT LINE MODIFIED.
*
         stemp = stemp + abs( cx( i ) )
   30 CONTINUE
      dzsum1 = stemp
      RETURN
*
*     End of DZSUM1
*
      END