dsyr.f

Go to the documentation of this file.

      SUBROUTINE dsyr  ( UPLO, N, ALPHA, X, INCX, A, LDA )
*     .. Scalar Arguments ..
      DOUBLE PRECISION   ALPHA
      INTEGER            INCX, LDA, N
      CHARACTER*1        UPLO
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), X( * )
*     ..
*
*  Purpose
*  =======
*
*  DSYR   performs the symmetric rank 1 operation
*
*     A := alpha*x*x' + A,
*
*  where alpha is a real scalar, x is an n element vector and A is an
*  n by n symmetric matrix.
*
*  Parameters
*  ==========
*
*  UPLO   - CHARACTER*1.
*           On entry, UPLO specifies whether the upper or lower
*           triangular part of the array A is to be referenced as
*           follows:
*
*              UPLO = 'U' or 'u'   Only the upper triangular part of A
*                                  is to be referenced.
*
*              UPLO = 'L' or 'l'   Only the lower triangular part of A
*                                  is to be referenced.
*
*           Unchanged on exit.
*
*  N      - INTEGER.
*           On entry, N specifies the order of the matrix A.
*           N must be at least zero.
*           Unchanged on exit.
*
*  ALPHA  - DOUBLE PRECISION.
*           On entry, ALPHA specifies the scalar alpha.
*           Unchanged on exit.
*
*  X      - DOUBLE PRECISION array of dimension at least
*           ( 1 + ( n - 1 )*abs( INCX ) ).
*           Before entry, the incremented array X must contain the n
*           element vector x.
*           Unchanged on exit.
*
*  INCX   - INTEGER.
*           On entry, INCX specifies the increment for the elements of
*           X. INCX must not be zero.
*           Unchanged on exit.
*
*  A      - DOUBLE PRECISION array of DIMENSION ( LDA, n ).
*           Before entry with  UPLO = 'U' or 'u', the leading n by n
*           upper triangular part of the array A must contain the upper
*           triangular part of the symmetric matrix and the strictly
*           lower triangular part of A is not referenced. On exit, the
*           upper triangular part of the array A is overwritten by the
*           upper triangular part of the updated matrix.
*           Before entry with UPLO = 'L' or 'l', the leading n by n
*           lower triangular part of the array A must contain the lower
*           triangular part of the symmetric matrix and the strictly
*           upper triangular part of A is not referenced. On exit, the
*           lower triangular part of the array A is overwritten by the
*           lower triangular part of the updated matrix.
*
*  LDA    - INTEGER.
*           On entry, LDA specifies the first dimension of A as declared
*           in the calling (sub) program. LDA must be at least
*           max( 1, n ).
*           Unchanged on exit.
*
*
*  Level 2 Blas routine.
*
*  -- Written on 22-October-1986.
*     Jack Dongarra, Argonne National Lab.
*     Jeremy Du Croz, Nag Central Office.
*     Sven Hammarling, Nag Central Office.
*     Richard Hanson, Sandia National Labs.
*
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
*     .. Local Scalars ..
      DOUBLE PRECISION   TEMP
      INTEGER            I, INFO, IX, J, JX, KX
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF     ( .NOT.lsame( uplo, 'U' ).AND.
     $         .NOT.lsame( uplo, 'L' )      )THEN
         info = 1
      ELSE IF( n.LT.0 )THEN
         info = 2
      ELSE IF( incx.EQ.0 )THEN
         info = 5
      ELSE IF( lda.LT.max( 1, n ) )THEN
         info = 7
      END IF
      IF( info.NE.0 )THEN
         CALL xerbla( 'DSYR  ', info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( ( n.EQ.0 ).OR.( alpha.EQ.zero ) )
     $   RETURN
*
*     Set the start point in X if the increment is not unity.
*
      IF( incx.LE.0 )THEN
         kx = 1 - ( n - 1 )*incx
      ELSE IF( incx.NE.1 )THEN
         kx = 1
      END IF
*
*     Start the operations. In this version the elements of A are
*     accessed sequentially with one pass through the triangular part
*     of A.
*
      IF( lsame( uplo, 'U' ) )THEN
*
*        Form  A  when A is stored in upper triangle.
*
         IF( incx.EQ.1 )THEN
            DO 20, j = 1, n
               IF( x( j ).NE.zero )THEN
                  temp = alpha*x( j )
                  DO 10, i = 1, j
                     a( i, j ) = a( i, j ) + x( i )*temp
   10             CONTINUE
               END IF
   20       CONTINUE
         ELSE
            jx = kx
            DO 40, j = 1, n
               IF( x( jx ).NE.zero )THEN
                  temp = alpha*x( jx )
                  ix   = kx
                  DO 30, i = 1, j
                     a( i, j ) = a( i, j ) + x( ix )*temp
                     ix        = ix        + incx
   30             CONTINUE
               END IF
               jx = jx + incx
   40       CONTINUE
         END IF
      ELSE
*
*        Form  A  when A is stored in lower triangle.
*
         IF( incx.EQ.1 )THEN
            DO 60, j = 1, n
               IF( x( j ).NE.zero )THEN
                  temp = alpha*x( j )
                  DO 50, i = j, n
                     a( i, j ) = a( i, j ) + x( i )*temp
   50             CONTINUE
               END IF
   60       CONTINUE
         ELSE
            jx = kx
            DO 80, j = 1, n
               IF( x( jx ).NE.zero )THEN
                  temp = alpha*x( jx )
                  ix   = jx
                  DO 70, i = j, n
                     a( i, j ) = a( i, j ) + x( ix )*temp
                     ix        = ix        + incx
   70             CONTINUE
               END IF
               jx = jx + incx
   80       CONTINUE
         END IF
      END IF
*
      RETURN
*
*     End of DSYR  .
*
      END