dsygs2.f

Go to the documentation of this file.

      SUBROUTINE dsygs2( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
*
*  -- LAPACK routine (version 3.0) --
*     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
*     Courant Institute, Argonne National Lab, and Rice University
*     February 29, 1992
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, ITYPE, LDA, LDB, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), B( LDB, * )
*     ..
*
*  Purpose
*  =======
*
*  DSYGS2 reduces a real symmetric-definite generalized eigenproblem
*  to standard form.
*
*  If ITYPE = 1, the problem is A*x = lambda*B*x,
*  and A is overwritten by inv(U')*A*inv(U) or inv(L)*A*inv(L')
*
*  If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
*  B*A*x = lambda*x, and A is overwritten by U*A*U` or L'*A*L.
*
*  B must have been previously factorized as U'*U or L*L' by DPOTRF.
*
*  Arguments
*  =========
*
*  ITYPE   (input) INTEGER
*          = 1: compute inv(U')*A*inv(U) or inv(L)*A*inv(L');
*          = 2 or 3: compute U*A*U' or L'*A*L.
*
*  UPLO    (input) CHARACTER
*          Specifies whether the upper or lower triangular part of the
*          symmetric matrix A is stored, and how B has been factorized.
*          = 'U':  Upper triangular
*          = 'L':  Lower triangular
*
*  N       (input) INTEGER
*          The order of the matrices A and B.  N >= 0.
*
*  A       (input/output) DOUBLE PRECISION array, dimension (LDA,N)
*          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
*          n by n upper triangular part of A contains the upper
*          triangular part of the matrix A, and the strictly lower
*          triangular part of A is not referenced.  If UPLO = 'L', the
*          leading n by n lower triangular part of A contains the lower
*          triangular part of the matrix A, and the strictly upper
*          triangular part of A is not referenced.
*
*          On exit, if INFO = 0, the transformed matrix, stored in the
*          same format as A.
*
*  LDA     (input) INTEGER
*          The leading dimension of the array A.  LDA >= max(1,N).
*
*  B       (input) DOUBLE PRECISION array, dimension (LDB,N)
*          The triangular factor from the Cholesky factorization of B,
*          as returned by DPOTRF.
*
*  LDB     (input) INTEGER
*          The leading dimension of the array B.  LDB >= max(1,N).
*
*  INFO    (output) INTEGER
*          = 0:  successful exit.
*          < 0:  if INFO = -i, the i-th argument had an illegal value.
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, HALF
      parameter( one = 1.0d0, half = 0.5d0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            K
      DOUBLE PRECISION   AKK, BKK, CT
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dscal, dsyr2, dtrmv, dtrsv, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DSYGS2', -info )
         RETURN
      END IF
*
      IF( itype.EQ.1 ) THEN
         IF( upper ) THEN
*
*           Compute inv(U')*A*inv(U)
*
            DO 10 k = 1, n
*
*              Update the upper triangle of A(k:n,k:n)
*
               akk = a( k, k )
               bkk = b( k, k )
               akk = akk / bkk**2
               a( k, k ) = akk
               IF( k.LT.n ) THEN
                  CALL dscal( n-k, one / bkk, a( k, k+1 ), lda )
                  ct = -half*akk
                  CALL daxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL dsyr2( uplo, n-k, -one, a( k, k+1 ), lda,
     $                        b( k, k+1 ), ldb, a( k+1, k+1 ), lda )
                  CALL daxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL dtrsv( uplo, 'Transpose', 'Non-unit', n-k,
     $                        b( k+1, k+1 ), ldb, a( k, k+1 ), lda )
               END IF
   10       CONTINUE
         ELSE
*
*           Compute inv(L)*A*inv(L')
*
            DO 20 k = 1, n
*
*              Update the lower triangle of A(k:n,k:n)
*
               akk = a( k, k )
               bkk = b( k, k )
               akk = akk / bkk**2
               a( k, k ) = akk
               IF( k.LT.n ) THEN
                  CALL dscal( n-k, one / bkk, a( k+1, k ), 1 )
                  ct = -half*akk
                  CALL daxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
                  CALL dsyr2( uplo, n-k, -one, a( k+1, k ), 1,
     $                        b( k+1, k ), 1, a( k+1, k+1 ), lda )
                  CALL daxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
                  CALL dtrsv( uplo, 'No transpose', 'Non-unit', n-k,
     $                        b( k+1, k+1 ), ldb, a( k+1, k ), 1 )
               END IF
   20       CONTINUE
         END IF
      ELSE
         IF( upper ) THEN
*
*           Compute U*A*U'
*
            DO 30 k = 1, n
*
*              Update the upper triangle of A(1:k,1:k)
*
               akk = a( k, k )
               bkk = b( k, k )
               CALL dtrmv( uplo, 'No transpose', 'Non-unit', k-1, b,
     $                     ldb, a( 1, k ), 1 )
               ct = half*akk
               CALL daxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
               CALL dsyr2( uplo, k-1, one, a( 1, k ), 1, b( 1, k ), 1,
     $                     a, lda )
               CALL daxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
               CALL dscal( k-1, bkk, a( 1, k ), 1 )
               a( k, k ) = akk*bkk**2
   30       CONTINUE
         ELSE
*
*           Compute L'*A*L
*
            DO 40 k = 1, n
*
*              Update the lower triangle of A(1:k,1:k)
*
               akk = a( k, k )
               bkk = b( k, k )
               CALL dtrmv( uplo, 'Transpose', 'Non-unit', k-1, b, ldb,
     $                     a( k, 1 ), lda )
               ct = half*akk
               CALL daxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
               CALL dsyr2( uplo, k-1, one, a( k, 1 ), lda, b( k, 1 ),
     $                     ldb, a, lda )
               CALL daxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
               CALL dscal( k-1, bkk, a( k, 1 ), lda )
               a( k, k ) = akk*bkk**2
   40       CONTINUE
         END IF
      END IF
      RETURN
*
*     End of DSYGS2
*
      END