dlarft.f

Go to the documentation of this file.

      SUBROUTINE dlarft( DIRECT, STOREV, N, K, V, LDV, TAU, T, LDT )
*
*  -- LAPACK auxiliary routine (version 3.0) --
*     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
*     Courant Institute, Argonne National Lab, and Rice University
*     February 29, 1992
*
*     .. Scalar Arguments ..
      CHARACTER          DIRECT, STOREV
      INTEGER            K, LDT, LDV, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   T( LDT, * ), TAU( * ), V( LDV, * )
*     ..
*
*  Purpose
*  =======
*
*  DLARFT forms the triangular factor T of a real block reflector H
*  of order n, which is defined as a product of k elementary reflectors.
*
*  If DIRECT = 'F', H = H(1) H(2) . . . H(k) and T is upper triangular;
*
*  If DIRECT = 'B', H = H(k) . . . H(2) H(1) and T is lower triangular.
*
*  If STOREV = 'C', the vector which defines the elementary reflector
*  H(i) is stored in the i-th column of the array V, and
*
*     H  =  I - V * T * V'
*
*  If STOREV = 'R', the vector which defines the elementary reflector
*  H(i) is stored in the i-th row of the array V, and
*
*     H  =  I - V' * T * V
*
*  Arguments
*  =========
*
*  DIRECT  (input) CHARACTER*1
*          Specifies the order in which the elementary reflectors are
*          multiplied to form the block reflector:
*          = 'F': H = H(1) H(2) . . . H(k) (Forward)
*          = 'B': H = H(k) . . . H(2) H(1) (Backward)
*
*  STOREV  (input) CHARACTER*1
*          Specifies how the vectors which define the elementary
*          reflectors are stored (see also Further Details):
*          = 'C': columnwise
*          = 'R': rowwise
*
*  N       (input) INTEGER
*          The order of the block reflector H. N >= 0.
*
*  K       (input) INTEGER
*          The order of the triangular factor T (= the number of
*          elementary reflectors). K >= 1.
*
*  V       (input/output) DOUBLE PRECISION array, dimension
*                               (LDV,K) if STOREV = 'C'
*                               (LDV,N) if STOREV = 'R'
*          The matrix V. See further details.
*
*  LDV     (input) INTEGER
*          The leading dimension of the array V.
*          If STOREV = 'C', LDV >= max(1,N); if STOREV = 'R', LDV >= K.
*
*  TAU     (input) DOUBLE PRECISION array, dimension (K)
*          TAU(i) must contain the scalar factor of the elementary
*          reflector H(i).
*
*  T       (output) DOUBLE PRECISION array, dimension (LDT,K)
*          The k by k triangular factor T of the block reflector.
*          If DIRECT = 'F', T is upper triangular; if DIRECT = 'B', T is
*          lower triangular. The rest of the array is not used.
*
*  LDT     (input) INTEGER
*          The leading dimension of the array T. LDT >= K.
*
*  Further Details
*  ===============
*
*  The shape of the matrix V and the storage of the vectors which define
*  the H(i) is best illustrated by the following example with n = 5 and
*  k = 3. The elements equal to 1 are not stored; the corresponding
*  array elements are modified but restored on exit. The rest of the
*  array is not used.
*
*  DIRECT = 'F' and STOREV = 'C':         DIRECT = 'F' and STOREV = 'R':
*
*               V = (  1       )                 V = (  1 v1 v1 v1 v1 )
*                   ( v1  1    )                     (     1 v2 v2 v2 )
*                   ( v1 v2  1 )                     (        1 v3 v3 )
*                   ( v1 v2 v3 )
*                   ( v1 v2 v3 )
*
*  DIRECT = 'B' and STOREV = 'C':         DIRECT = 'B' and STOREV = 'R':
*
*               V = ( v1 v2 v3 )                 V = ( v1 v1  1       )
*                   ( v1 v2 v3 )                     ( v2 v2 v2  1    )
*                   (  1 v2 v3 )                     ( v3 v3 v3 v3  1 )
*                   (     1 v3 )
*                   (        1 )
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   VII
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemv, dtrmv
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( lsame( direct, 'F' ) ) THEN
         DO 20 i = 1, k
            IF( tau( i ).EQ.zero ) THEN
*
*              H(i)  =  I
*
               DO 10 j = 1, i
                  t( j, i ) = zero
   10          CONTINUE
            ELSE
*
*              general case
*
               vii = v( i, i )
               v( i, i ) = one
               IF( lsame( storev, 'C' ) ) THEN
*
*                 T(1:i-1,i) := - tau(i) * V(i:n,1:i-1)' * V(i:n,i)
*
                  CALL dgemv( 'Transpose', n-i+1, i-1, -tau( i ),
     $                        v( i, 1 ), ldv, v( i, i ), 1, zero,
     $                        t( 1, i ), 1 )
               ELSE
*
*                 T(1:i-1,i) := - tau(i) * V(1:i-1,i:n) * V(i,i:n)'
*
                  CALL dgemv( 'No transpose', i-1, n-i+1, -tau( i ),
     $                        v( 1, i ), ldv, v( i, i ), ldv, zero,
     $                        t( 1, i ), 1 )
               END IF
               v( i, i ) = vii
*
*              T(1:i-1,i) := T(1:i-1,1:i-1) * T(1:i-1,i)
*
               CALL dtrmv( 'Upper', 'No transpose', 'Non-unit', i-1, t,
     $                     ldt, t( 1, i ), 1 )
               t( i, i ) = tau( i )
            END IF
   20    CONTINUE
      ELSE
         DO 40 i = k, 1, -1
            IF( tau( i ).EQ.zero ) THEN
*
*              H(i)  =  I
*
               DO 30 j = i, k
                  t( j, i ) = zero
   30          CONTINUE
            ELSE
*
*              general case
*
               IF( i.LT.k ) THEN
                  IF( lsame( storev, 'C' ) ) THEN
                     vii = v( n-k+i, i )
                     v( n-k+i, i ) = one
*
*                    T(i+1:k,i) :=
*                            - tau(i) * V(1:n-k+i,i+1:k)' * V(1:n-k+i,i)
*
                     CALL dgemv( 'Transpose', n-k+i, k-i, -tau( i ),
     $                           v( 1, i+1 ), ldv, v( 1, i ), 1, zero,
     $                           t( i+1, i ), 1 )
                     v( n-k+i, i ) = vii
                  ELSE
                     vii = v( i, n-k+i )
                     v( i, n-k+i ) = one
*
*                    T(i+1:k,i) :=
*                            - tau(i) * V(i+1:k,1:n-k+i) * V(i,1:n-k+i)'
*
                     CALL dgemv( 'No transpose', k-i, n-k+i, -tau( i ),
     $                           v( i+1, 1 ), ldv, v( i, 1 ), ldv, zero,
     $                           t( i+1, i ), 1 )
                     v( i, n-k+i ) = vii
                  END IF
*
*                 T(i+1:k,i) := T(i+1:k,i+1:k) * T(i+1:k,i)
*
                  CALL dtrmv( 'Lower', 'No transpose', 'Non-unit', k-i,
     $                        t( i+1, i+1 ), ldt, t( i+1, i ), 1 )
               END IF
               t( i, i ) = tau( i )
            END IF
   40    CONTINUE
      END IF
      RETURN
*
*     End of DLARFT
*
      END